UO Evolution

Tech Support => Coding Corner => Topic started by: Evolution on March 17, 2016, 06:30:58 PM

Title: Skill Macros - UO Steam
Post by: Evolution on March 17, 2016, 06:30:58 PM
Here is a nice collection of Skill Macros to help train your character's skills with UO Steam

For more info and documentation you can visit these UO Steam links

UO Steam Wiki
http://uoevolution.com/wiki/index.php/UO_Steam_Wiki (http://uoevolution.com/wiki/index.php/UO_Steam_Wiki)

UOE UO Steam Macro Library
http://uoevolution.com/forum/index.php?topic=7706.0 (http://uoevolution.com/forum/index.php?topic=7706.0)

UOE UO Razor Macro Library
http://uoevolution.com/forum/index.php?topic=7730.0 (http://uoevolution.com/forum/index.php?topic=7730.0)
Title: Re: Skill Macros - UO Steam - Alchemy Script
Post by: Evolution on March 17, 2016, 06:33:24 PM


//This macro is designed for         //
//training alchemy from 30. Have //
//5 empty kegs on you and a lot  //
//of mortars and pestals. This      //
//macro only makes PVP worthy  //
//potions to minimize waste.       //
//Turn on loop and click play!      //


if skill 'alchemy' < 60 and not @findobject 'TR'
  headmsg 'Select Total Refresh Keg'
  promptalias 'TR'
endif
if skill 'alchemy' < 70 and not @findobject 'GA'
  headmsg 'Select Greater Agility Keg'
  promptalias 'GA'
endif
if skill 'alchemy' < 80 and not @findobject 'GS'
  headmsg 'Select Greater Strength Keg'
  promptalias 'GS'
endif
if skill 'alchemy' < 90 and not @findobject 'GH'
  headmsg 'Select Greater Heal Keg'
  promptalias 'GH'
endif
if skill 'alchemy' < 100 and not @findobject 'GC'
  headmsg 'Select Greater Cure Keg'
  promptalias 'GC'
endif
if skill 'alchemy' < 30
  headmsg 'Buy more skill!'
  stop
elseif skill 'alchemy' < 60
  if usetype 0xe9b 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 1
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 9
    waitforgump 0x38920abd 2000
  endif
  if @findtype 0xf0b 0x0 'backpack'
    moveitem 'found' 'TR'
    pause 600
  endif
elseif skill 'alchemy' < 70
  if usetype 0xe9b 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 9
    waitforgump 0x38920abd 2000
  endif
  if @findtype 0xf08 0x0 'backpack'
    moveitem 'found' 'GA'
    pause 600
  endif
elseif skill 'alchemy' < 80
  if usetype 0xe9b 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 29
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 9
    waitforgump 0x38920abd 2000
  endif
  if @findtype 0xf09 0x0 'backpack'
    moveitem 'found' 'GS'
    pause 600
  endif
elseif skill 'alchemy' < 90
  if usetype 0xe9b 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 16
    waitforgump 0x38920abd 2000
  endif
  if @findtype 0xf0c 0x0 'backpack'
    moveitem 'found' 'GH'
    pause 600
  endif
elseif skill 'alchemy' < 100
  if usetype 0xe9b 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 43
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 16
    waitforgump 0x38920abd 2000
  endif
  if @findtype 0xf07 0x0 'backpack'
    moveitem 'found' 'GC'
    pause 600
  endif
else
  headmsg 'Alchemy complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Anatomy Script
Post by: Evolution on March 17, 2016, 06:36:48 PM


//   This macro is designed for   //
//    training anatomy from 0.    //
//  Turn on loop and click play!  //

if not @findalias 'anat'
  headmsg 'Select the person to train anatomy on'
  promptalias 'anat'
endif
if skill 'anatomy' < 100
  useskill 'anatomy'
  waitfortarget 2000
  target! 'anat'
  pause 1000
else
  headmsg 'Anatomy complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam -Arms Lore
Post by: Evolution on March 17, 2016, 06:40:45 PM



//   This macro is designed for   //
//  training arms lore from 0. I   //
//  typically target my dagger.   //
//  Turn on loop and click play!  //




if not @findalias 'lore'
  headmsg 'Select the item to train arms lore on'
  promptalias 'lore'
endif
if skill 'arms lore' < 100
  useskill 'arms lore'
  waitfortarget 2000
  target! 'lore'
  pause 1000
else
  headmsg 'Arms Lore Complete!'
  stop
endif

Title: Re: Skill Macros - UO Steam
Post by: Smilingdeath on March 17, 2016, 10:16:53 PM
Add item identification to the arms lore macro and train both up over night.


The one I used is...
useskill 'Arms Lore'
waitfortarget 15000
target! 0x41e1ecac
pause 6500
useskill 'Item Identification'
waitfortarget 15000
target! 0x41e1ecac
pause 6500


If I remember correctly I targeted the Astral Demon Helm, but you can set it to target what ever item you would like and run both skills for the night when you head to bed. 
Title: Re: Skill Macros - UO Steam - Begging Script
Post by: Evolution on March 19, 2016, 01:34:59 PM



//   This macro is designed for     //
//    training begging from 0.       //
// I suggest training in an shop  //
//     with plenty of vendors        //
//       wandering around.           //
//  Turn on loop and click play!   //


if skill 'begging' < 100
  getfriend 'friend' 'innocent' 'closest'
  useskill 'begging'
  waitfortarget 2000
  target! 'found'
  pause 13000
else
  headmsg 'Begging complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Blacksmith
Post by: Evolution on March 19, 2016, 01:36:29 PM



//    Uses tongs. This macro is    //
//      designed for training         //
//      blacksmithy from 50.         //
//  Turn on loop and click play!  //




if skill 'Blacksmithy' <  50
  headmsg 'You should have started with 50 skill!'
  stop
elseif skill 'Blacksmithy' <= 93
  if usetype 0xfbb 'any' 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 50
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 16
    pause 2000
  endif
  if usetype 0xfbb 'any' 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 14
    waitfortarget 15000
    @targettype! 0x1403 0x0 'backpack'
  endif
elseif skill 'blacksmithy' < 100
  if usetype 0xfbb 'any' 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 15
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 16
    pause 2000
  endif
  if usetype 0xfbb 'any' 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 14
    waitfortarget 15000
    @targettype! 0x1413 0x0 'backpack'
  endif
else
  headmsg 'Blacksmithy complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Carpentry
Post by: Evolution on March 19, 2016, 01:38:36 PM



//   This macro is designed for          //
//  training carpentry from 30.          //
// It uses standard saws. Due to     //
//  the weight of boards, it is           //
// written to be used in a house      //
// with a chest to restock from.        //


//   Warning: Throws away deeds!  //
//           Bank them!                        //
//  Turn on loop and click play!        //


if not @listexists 'carpjunk'
  createlist 'carpjunk'
  pushlist 'carpjunk' 0x9aa
  pushlist 'carpjunk' 0xe3f
  pushlist 'carpjunk' 0x14f0 // DEED! WATCH OUT!
  pushlist 'carpjunk' 0xb4a
  pushlist 'carpjunk' 0xe89
  pushlist 'carpjunk' 0x13f8
endif
if not @findtype 0x1034 0x0 'backpack'
  headmsg 'Get more saws!'
  stop
endif
if not @findobject 'trash'
  headmsg 'Select your trash barrel'
  promptalias 'trash'
endif
if not @findobject 'restock'
  headmsg 'Select the container with your boards'
  promptalias 'restock'
  useobject 'restock'
endif
if @counttype 0x1bd7 0x0 'backpack' < 20
  movetype 0x1bd7 'restock' 'backpack' 0 0 0 0x0 150
  pause 1000
endif
if skill 'carpentry' < 30
  headmsg 'Buy more skill!'
  stop
elseif skill 'carpentry' < 40
  if usetype 0x1034 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 15
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 2
    waitforgump 0x38920abd 2000
  endif
elseif skill 'carpentry' < 50
  if usetype 0x1034 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 15
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 16
    waitforgump 0x38920abd 2000
  endif
elseif skill 'carpentry' < 70
  if usetype 0x1034 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 36
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 44
    waitforgump 0x38920abd 2000
  endif
elseif skill 'carpentry' < 75
  if usetype 0x1034 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 72
    waitforgump 0x38920abd 2000
  endif
elseif skill 'carpentry' < 90
  if usetype 0x1034 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 9
    waitforgump 0x38920abd 2000
  endif
elseif skill 'carpentry' < 100
  if usetype 0x1034 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 16
    waitforgump 0x38920abd 2000
  endif
else
  headmsg 'Carpentry completed!'
  stop
endif
if contents 'backpack' > 115 or diffweight < 20
  for 0 to carpjunk
    while @movetype carpjunk[] 'backpack' 'trash'
    endwhile
  endfor
endif
Title: Re: Skill Macros - UO Steam - Cartography Script
Post by: Evolution on March 19, 2016, 01:41:07 PM



//   This macro is designed for           //
// training cartography from 30.        //
//  Make sure you have mapmakers  //
//  pens on you and not scribes!       //
//  Turn on loop and click play!          //




if not @findtype 0xfbf 0x0 'backpack'
  headmsg 'Get more Pens!'
  stop
endif
if not @findobject 'trash'
  headmsg 'Select your trash barrel'
  promptalias 'trash'
endif
if not @findobject 'restock'
  headmsg 'Select the container with your blank scrolls'
  promptalias 'restock'
  useobject 'restock'
endif
if @counttype 0xef3 0x0 'backpack' == 0
  movetype 0xef3 'restock' 'backpack' 0 0 0 0x0 150
  pause 1000
endif
if skill 'Cartography' < 30
  headmsg 'Buy more skill from NPC!'
  stop
elseif skill 'Cartography' < 50
  if usetype 0xfbf 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 1
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 2
    waitforgump 0x38920abd 2000
  endif
elseif skill 'Cartography' < 65
  if usetype 0xfbf 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 1
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 9
    waitforgump 0x38920abd 2000
  endif
elseif skill 'Cartography' < 99.5
  if usetype 0xfbf 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 1
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 23
    waitforgump 0x38920abd 2000
  endif
else
  headmsg 'Macro complete! Train to 100 by deciphering level 3 and 4 treasure maps.'
  stop
endif
if contents 'backpack' > 115 or diffweight < 20
  while movetype 0x14ec 'backpack' 'trash'
    pause 500
  endwhile
endif

Title: Re: Skill Macros - UO Steam - Cooking Script
Post by: Evolution on March 19, 2016, 01:42:39 PM



//   This macro is designed for     //
//  training cooking from 0. This   //
//  macro cooks raw fish steaks  //
// and skillets to train cooking.   //
//  Turn on loop and click play!    //


if not @findobject 'steakbox'
  headmsg 'Select the box with your fishsteaks'
  promptalias 'steakbox'
endif
if not @findtype 0x97f 'any' 'backpack'
  headmsg 'Get more skillets!'
  stop
endif
if not @findtype 0x97a 'any' 'steakbox'
  headmsg 'Get more raw fish steaks!'
  stop
endif
if skill 'cooking' < 100
  movetype 0x97a 'steakbox' 'backpack' 0 0 0 0x0 1
  pause 600
  if usetype 0x97f 'any' 'backpack'
    waitforgump 0x38920abd 2000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 2000
    replygump 0x38920abd 16
    waitforgump 0x38920abd 2000
  endif
else
  headmsg 'Cooking complete!'
  stop
Title: Re: Skill Macros - UO Steam - Eval Int Script
Post by: Evolution on March 19, 2016, 01:48:43 PM



//   This macro is designed for   //
//      training evaluating           //
//      intelligence from 0.           //
//  Turn on loop and click play!  //


if not @findalias 'eval'
  headmsg 'Select the person to train evaluating intelligence on'
  promptalias 'eval'
endif
if skill 'evaluating intelligence' < 100
  useskill 'evaluating intelligence'
  waitfortarget 2000
  target! 'eval'
  pause 1000
else
  headmsg 'Evaluating Intelligence Complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Fishing Script
Post by: Evolution on March 19, 2016, 01:50:01 PM



//   This macro is designed for   //
//  training fishing from a boat. //
//     It uses a fishing pole.       //
//   Stand in front of the mast.  //
//  Turn on loop and click play!  //


if not @findobject 'pole'
  if @findtype 0xdc0 0x0 'self'
    setalias 'pole' 'found'
    pause 100
  else
    headmsg 'get a pole'
  endif
endif
clearjournal
if skill 'fishing' < 100
  while not @injournal 'biting here'
    if useobject 'pole'
      waitfortarget 2000
      targettileoffset! -4 -4 -3
      pause 9000
    endif
    if useobject 'pole'
      waitfortarget 2000
      targettileoffset! -4 4 -3
      pause 9000
    endif
    if useobject 'pole'
      waitfortarget 2000
      targettileoffset! 4 -4 -3
      pause 9000
    endif
    if useobject 'pole'
      waitfortarget 2000
      targettileoffset! 4 4 -3
      pause 9000
    endif
  endwhile
  for 15
    msg 'forward one'
    pause 1000
  endfor
else
  headmsg 'Fishing complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Healing Script
Post by: Evolution on March 19, 2016, 01:52:15 PM



//   This macro is designed for     //
//  training healing from 0. It       //
// requires a magical wizard hat. //
//  Turn on loop and click play!    //


if not @findalias 'hat'
  headmsg "Select your magical wizard's hat"
  promptalias 'hat'
endif
if not @findtype 0xe21 'any' 'backpack'
  headmsg 'Get more bandaids!'
  stop
endif
if skill 'healing' < 100
  equipitem 'hat' 6
  pause 600
  moveitem 'hat' 'backpack'
  pause 600
  bandageself
  pause 6000
  equipitem 'hat' 6
  pause 600
  moveitem 'hat' 'backpack'
  pause 7000
else
  headmsg 'Healing complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Hiding Script
Post by: Evolution on March 19, 2016, 01:53:17 PM



//   This macro is designed for   //
//    training hiding from 0.        //
//  Turn on loop and click play!  //


if skill 'hiding' < 100
  useskill 'hiding'
  pause 11000
else
  headmsg 'Hiding complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Hide and Snoop Script
Post by: Evolution on March 19, 2016, 01:54:53 PM



//   This macro is designed for     //
//    training both hiding and       //
//     snooping from 0. It is          //
// easiest to train by using two  //
//        clients at once.                //
//  Turn on loop and click play!   //


if skill 'snooping' < 100
  if not @findobject 'snoop' or not @inrange 'snoop' 1
    headmsg 'Select the person to snoop'
    promptalias 'snoop'
  else
    @findlayer 'snoop' 21
    useobject! 'found'
    pause 600
  endif
endif
if skill 'hiding' < 100
  useskill 'hiding'
endif
if skill 'hiding' == 100 and skill 'snooping' == 100
  headmsg 'Hiding and snooping complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Inscription
Post by: Evolution on March 19, 2016, 01:55:53 PM



//   This macro is designed for   //
// training inscription from 30.   //
//  It is intended for characters //
//     with 40+ intelligence.        //
//  Turn on loop and click play!  //


if not @findtype 0xfbf 0x0 'backpack'
  headmsg 'Get more scribes pens!'
  stop
endif
if @ingump 0x38920abd 'You lack the required'
  useskill 'meditation'
  while mana < maxmana
  endwhile
endif
if @ingump 0x38920abd 'You do not have enough'
  headmsg 'Get more supplies!'
  stop
endif
if skill 'inscription' < 30
  headmsg 'Buy more skill!'
  stop
elseif skill 'inscription' < 55
  if usetype 0xfbf
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 51
    waitforgump 0x38920abd 2000
  endif
elseif skill 'inscription' < 75
  if usetype 0xfbf
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 36
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 30
    waitforgump 0x38920abd 2000
  endif
elseif skill 'inscription' < 95
  if usetype 0xfbf
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 43
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 23
    waitforgump 0x38920abd 2000
  endif
elseif skill 'inscription' < 100
  if usetype 0xfbf
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 50
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 9
    waitforgump 0x38920abd 2000
  endif
else
  headmsg 'Inscription complete!'
  stop
endif

Title: Re: Skill Macros - UO Steam
Post by: Evolution on March 19, 2016, 01:57:25 PM



//   This macro is designed for    //
//  training item identification     //
//  from 0. I typically target my  //
//            dagger.                       //
//  Turn on loop and click play!  //


if not @findalias 'itemid'
  headmsg 'Select the item to train ID on'
  promptalias 'itemid'
endif
if skill 'item identification' < 100
  useskill 'item identification'
  waitfortarget 2000
  target! 'itemid'
  pause 1000
else
  headmsg 'Item Identification Complete!'
  stop
endif

Title: Re: Skill Macros - UO Steam - Magery Script
Post by: Evolution on March 19, 2016, 01:58:44 PM



//   This macro is designed for     //
// training magery from 30. It is  //
//  intended for characters with  //
//        40+ intelligence.              //
//  Turn on loop and click play!   //


if @injournal 'insufficient mana'
  clearjournal
  useskill 'meditation'
  while mana < maxmana
  endwhile
else
  if skill 'magery' < 30
    headmsg 'Buy more skill!'
    stop
  elseif skill 'magery' < 45
    cast 'bless' 'self'
    pause 1000
  elseif skill 'magery' < 55
    cast 'mana drain' 'self'
    pause 1000
  elseif skill 'magery' < 75
    cast 'invisibility' 'self'
    while waitingfortarget
    endwhile
    pause 1000
  elseif skill 'magery' < 100
    cast 'mana vampire' 'self'
    pause 1000
  else
    headmsg 'Magery complete!'
    stop
  endif
endif

Title: Re: Skill Macros - UO Steam - Magery and Resist Script
Post by: Evolution on March 19, 2016, 02:00:01 PM



//   This macro is designed for    //
//    training both magery and    //
// resist from 30. It is intended  //
//     for characters with 40+      //
//          intelligence.                   //
//  Turn on loop and click play!   //


if skill 'magery' < 100
  if @injournal 'insufficient mana'
    clearjournal
    useskill 'meditation'
    while mana < maxmana
    endwhile
  else
    if skill 'magery' < 30
      headmsg 'Buy more skill!'
      stop
    elseif skill 'magery' < 45
      cast 'bless' 'self'
      pause 1000
    elseif skill 'magery' < 55
      cast 'mana drain' 'self'
      pause 1000
    elseif skill 'magery' < 75
      cast 'invisibility' 'self'
      pause 1000
    elseif skill 'magery' < 100
      cast 'mana vampire' 'self'
      pause 1000
    else
      headmsg 'Magery complete!'
      stop
    endif
  endif
elseif skill 'resisting spells' < 100
  if @injournal 'insufficient mana'
    clearjournal
    useskill 'meditation'
    while mana < maxmana
    endwhile
  else
    cast 'mana vampire' 'self'
    pause 1000
  endif
else
  headmsg 'Magery and resisting spells complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Musicianship Script
Post by: Evolution on March 19, 2016, 02:01:15 PM



//   This macro is designed for    //
//  training musicianship from 0. //
//   This macro uses lap harps.   //
//  Turn on loop and click play!   //


if not @findtype 0xeb2 0x0 'backpack'
  headmsg 'Get more lap harps!'
  stop
endif
if skill 'musicianship' < 100
  usetype 0xeb2 0x0 'backpack'
  pause 11000
else
  headmsg 'Musicianship complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Peacemaking Script
Post by: Evolution on March 19, 2016, 02:02:31 PM



//   This macro is designed for      //
//  training peacemaking from 0.  //
//   This macro uses lap harps.    //
//  Turn on loop and click play!    //


if not @findtype 0xeb2 0x0 'backpack'
  headmsg 'Get more lap harps!'
  stop
endif
if skill 'peacemaking' < 100
  useskill 'peacemaking'
  waitfortarget 2000
  if @injournal 'what instrument'
    targettype! 0xeb2 0x0 'backpack'
    waitfortarget 2000
    target! 'self'
    clearjournal
    pause 11000
  else
    target! 'self'
    pause 11000
  endif
else
  headmsg 'Peacemaking Complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Poisoning Skill Script
Post by: Evolution on March 19, 2016, 02:05:18 PM



//   This macro is designed for          //
//  training poisoning from 30.          //
//    Due to the fact that this            //
//  macro uses kegs, it is easier       //
//    to macro from your house.        //
// Make sure you have 50+ greater //
//    cure potions on you and a        //
//         piece of food.                       //
//  Turn on loop and click play!        //


if skill 'poisoning' < 30 not @findobject 'LesserPoison'
  headmsg 'Select the lesser poison keg'
  promptalias 'LesserPoison'
endif
if skill 'poisoning' < 40 not @findobject 'Poison'
  headmsg 'Select the poison keg'
  promptalias 'Poison'
endif
if skill 'poisoning' < 68 not @findobject 'GreaterPoison'
  headmsg 'Select the greater poison keg'
  promptalias 'GreaterPoison'
endif
if not @findobject 'Food' 'any' 'backpack'
  headmsg 'Select a piece of food to be poisoned'
  promptalias 'Food'
endif
if not @findtype 0xf07 0x0 'backpack'
  headmsg 'Get some greater cure potions!
  stop
endif
if skill 'poisoning' < 30
  headmsg 'Buy more poisoning!'
  stop
elseif skill 'poisoning' < 40
  useobject! 'LesserPoison'
  pause 600
  useskill 'Poisoning'
  waitfortarget 2000
  targettype! 0xf0a 0x0 'backpack'
  waitfortarget 2000
  target! 'Food'
  pause 1000
  if poisoned 'self'
    usetype! 0xf07 0x0 'backpack'
  endif
  pause 10000
elseif skill 'poisoning' < 68
  useobject! 'Poison'
  pause 600
  useskill 'Poisoning'
  waitfortarget 2000
  targettype! 0xf0a 0x0 'backpack'
  waitfortarget 2000
  target! 'Food'
  pause 1000
  if poisoned 'self'
    usetype! 0xf07 0x0 'backpack'
  endif
  pause 10000
elseif skill 'poisoning' < 100
  useobject 'GreaterPoison'
  pause 600
  useskill 'Poisoning'
  waitfortarget 2000
  targettype! 0xf0a 0x0 'backpack'
  waitfortarget 2000
  target! 'Food'
  pause 1000
  if poisoned 'self'
    usetype! 0xf07 0x0 'backpack'
  endif
  pause 10000
else
  headmsg 'Poisoning complete!'
  stop
endif

Title: Re: Skill Macros - UO Steam - Resist Script
Post by: Evolution on March 19, 2016, 02:07:47 PM



//   This macro is designed for     //
//  the caster(s) of the resist.      //
//   This macro can train from 0    //
//      and is to be used in            //
//   conjunction with the below    //
//       recipient's macro.               //
//  Turn on loop and click play!     //


if not @findobject 'training'
  headmsg 'Target the person who is training resist'
  promptalias 'training'
endif
if @injournal 'insufficient mana'
  clearjournal
  useskill 'meditation'
  while mana < maxmana
  endwhile
else
  cast 'mana vampire' 'training'
  pause 1000
endif
if @injournal '1122334455'
  headmsg 'Resist complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Snoop Skill Script
Post by: Evolution on March 19, 2016, 02:09:15 PM



//   This macro is designed for   //
//    training snooping from 0.   //
//  Turn on loop and click play!  //


if not @findobject 'snoop' or not @inrange 'snoop' 1
  headmsg 'Select the person to snoop'
  promptalias 'snoop'
endif
if skill 'snooping' < 100
  @findlayer 'snoop' 21
  useobject! 'found'
  pause 600
else
  headmsg 'Snooping complete!'
  stop
endif
Title: Re: Skill Macros - UO Steam - Stealing Script
Post by: Evolution on March 19, 2016, 02:11:05 PM



//    The easiest way to train    //
// stealing is in your own house, //
//   from a secure container. If  //
// you train in a dungeon, remove //
//    the '//' from the last 2    //
//  lines and stand 1 tile north  //
//  of the container. This macro  //
//  uses empty bottles to train.  //
//  Turn on loop and click play!  //


if not @findalias 'host'
  headmsg 'Select host container to steal from, typically a secured house container'
  promptalias 'host'
  useobject 'host'
  pause 600
endif
if skill 'stealing' < 100
  @findtype 0xf0e 0x0 'host'
  useskill 'stealing'
  waitfortarget 2000
  target! 'found'
  pause 600
  if @injournal 'You success'
    movetype 0xf0e 'backpack' 'host'
    clearjournal
    pause 10000
  else
    pause 10000
  endif
else
  headmsg 'Stealing complete!'
  stop
endif
//moveitemoffset 'host' 'ground' 0 1 0
//pause 600

Title: Re: Skill Macros - UO Steam - Stealth Script
Post by: Evolution on March 19, 2016, 02:12:08 PM



//  Go to any public moongate for //
//   this to work. Also, bring a    //
//   ringmail tunic and sleeves.  //
//    This macrois designed for   //
//    training stealth from 0.       //
//  Turn on loop and click play!  //


if skill 'hiding' < 80
  headmsg 'Train your hiding to 80.0 first!'
  stop
endif
if not @findobject 'chest' and not @findtype 0x13ec 'any' 'self'
  headmsg 'Buy a ringmail tunic'
  stop
else
  setalias 'chest' 'found'
endif
if not @findobject 'arms' and not @findtype 0x13ee 'any' 'self'
  headmsg 'Buy ringmail sleeves'
  stop
else
  setalias 'arms' 'found'
endif
if skill 'stealth' < 80
  if usetype 0xf6c 'any' 'ground'
    waitforgump 0xe0e675b8 15000
    replygump 0xe0e675b8 1 1
    pause 10000
    useskill 'stealth'
    pause 600
  endif
  if usetype 0xf6c 'any' 'ground'
    waitforgump 0xe0e675b8 15000
    replygump 0xe0e675b8 1 0
    pause 10000
    useskill 'stealth'
    pause 600
  endif
elseif skill 'stealth' < 100
  if not @findlayer 'self' 13
    @equipitem 'chest' 13
    pause 600
  endif
  if not @findlayer 'self' 19
    @equipitem 'arms' 19
    pause 600
  endif
  if usetype 0xf6c 'any' 'ground'
    waitforgump 0xe0e675b8 15000
    replygump 0xe0e675b8 1 1
    pause 10000
    useskill 'stealth'
    pause 600
  endif
  if usetype 0xf6c 'any' 'ground'
    waitforgump 0xe0e675b8 15000
    replygump 0xe0e675b8 1 0
    pause 10000
    useskill 'stealth'
    pause 600
  endif
endif

Title: Re: Skill Macros - UO Steam - Tailoring Script
Post by: Evolution on March 19, 2016, 02:13:20 PM



//     Uses a sewing kit. This      //
//      macro is designed for       //
//   training tailoring from 30.    //
//  Turn on loop and click play!  //




if skill 'Tailoring' < 30
  headmsg "Buy skill from an NPC!"
  stop
elseif skill 'Tailoring' < 41.4
  if usetype 0xf9d 0x0 'backpack'
    replygump 0x38920abd 15
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 2
    waitforgump 0x38920abd 15000
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x152e 0x0 'backpack'
    endif
  endif
elseif skill 'Tailoring' < 54
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 51
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x1515 0x0 'backpack'
    endif
  endif
elseif skill 'Tailoring' < 74.6
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 58
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x1f03 0x0 'backpack'
    endif
  endif
elseif skill 'Tailoring' < 99
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 22
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 23
    pause 2000
    if diffweight < 20
      if usetype 0xf9f 0x0 'backpack'
        waitfortarget 2000
        @targettype! 0x175d 0x7d1 'backpack'
      endif
    endif
  endif
elseif skill 'tailoring' < 100
  if usetype 0xf9d 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 43
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 30
    pause 2000
    if usetype 0xf9f 0x0 'backpack'
      waitfortarget 2000
      @targettype! 0x13db 0x0 'backpack'
    endif
  endif
else
  headmsg 'Tailoring complete!'
  stop
endif

Title: Re: Skill Macros - UO Steam - Tinkering Script
Post by: Evolution on March 19, 2016, 02:15:05 PM



//    Uses a standard tool kit.     //
//   This macro is designed for   //
//   training tinkering from 30.   //
//  Warning: Throws away newbied  //
//      scissors! Bank them!      //
//  Turn on loop and click play!  //


if not @listexists 'tinkjunk'
  createlist 'tinkjunk'
  pushlist 'tinkjunk' 0xf9f // SCISSORS! WATCH OUT!
  pushlist 'tinkjunk' 0xf9d
  pushlist 'tinkjunk' 0xfbb
  pushlist 'tinkjunk' 0x14fc
  pushlist 'tinkjunk' 0x1849
endif
if @counttype 0x1eb8 'any' 'backpack' < 2
  if usetype 0x1eb8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 23
    waitforgump 0x38920abd 15000
  endif
endif
if not @findobject 'trash'
  headmsg 'Select your trash barrel'
  promptalias 'trash'
endif
if skill 'tinkering' < 30
  headmsg 'Buy more tinkering skill!'
  stop
elseif skill 'tinkering' < 40
  if usetype 0x1eb8 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 2
    waitforgump 0x38920abd 2000
  endif
elseif skill 'tinkering' < 65
  if usetype 0x1eb8 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 44
    waitforgump 0x38920abd 2000
  endif
elseif skill 'tinkering' < 75
  if usetype 0x1eb8 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 86
    waitforgump 0x38920abd 2000
  endif
elseif skill 'tinkering' < 94
  if usetype 0x1eb8 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 8
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 121
    waitforgump 0x38920abd 2000
  endif
elseif skill 'tinkering' < 100
  if usetype 0x1eb8 0x0 'backpack'
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 29
    waitforgump 0x38920abd 15000
    replygump 0x38920abd 51
    waitforgump 0x38920abd 2000
  endif
else
  headmsg 'Tinkering complete!'
  stop
endif
if contents 'backpack' > 115 or diffweight < 20
  for 0 to tinkjunk
    while @movetype tinkjunk[] 'backpack' 'trash'
    endwhile
  endfor
endif

Title: Re: Skill Macros - UO Steam
Post by: Smilingdeath on March 22, 2016, 09:13:30 PM
In regards to the cooking macro posted on page one.


Use a tool box key and withdraw a skillet with 5000 uses, or buy one off a vendor.



You can make dough till level 90+ then switch to making the egg bombs instead.  Uses water and flour.  The water just buy 1 pitcher from the bartenders near Brit bank, and is refillable at a water trough. The flour can be purchased from a baker.  1 bag of flour costs 3 gold and is good for 2-3 attempts at making the dough.


Place a water trough in you house or a friends house, and use the record function and make 1 dough, then refill the pitcher.  End the recording.  Copy and paste the dough making section 2 times and the refill of the water pitcher is placed after the third dough making attempt. So you will attempt to make the dough 3 times and the refill the water pitcher (can be used 4 times before it is empty).


It is cheaper in the long run, although the dough has no use unless you continue to make items using the dough.


Switch the making flour bombs (cooking version of the smoke bomb) after reaching level 90.  Uses eggs and flour. Eggs are purchased from a farmer and the flour from the baker.


 A side note here... At 90+ Alchemy you can make the smoke bombs instead of potions.


For both recipes... Put a cooking talisman on and increase the base chance to make one until the modified chance of success reaches approximately 60-65% range, then remove the talisman.  This can be done for each type of crafting while leveling it up as well.


Read here on how to get a crafting talisman.   
http://uoevolution.com/forum/index.php?topic=7741.0


If I remember I will post my macro from when I levelled up cooking to 112.4 when I get to the house, it only took a hour or two.  Even with trips to go get more flour and eggs.
Title: Re: Skill Macros - UO Steam
Post by: PontiusPilate on December 06, 2016, 08:29:06 PM
It keeps telling me error line ten on the cooking macro and it wont continue.
Title: Re: Skill Macros - UO Steam
Post by: Thunder on November 10, 2017, 04:50:13 AM
Didn't See Necro:

//========================
//Azrael The Angel Of Death
//(Night666)
//========================
//Death Necro Trainer
//========================
//You will need a LRC (LMC optional)
//Change the pause if lag or no FC & FCR present
//Change target this script was made in a free shard
//with custom Trainer Npc.
//========================
//Training
if skill 'Necromancy' < 110 and skill 'Necromancy' >= 40
  //Pain spike
  if skill 'Necromancy' < 40
    cast 'Pain Spike'
    waitfortarget 15000
    //Change Target
    target! 0x15ba7
    //Horrific Beast
  elseif skill 'Necromancy' >= 40 and skill 'Necromancy' < 70
    cast 'Horrific Beast'
    //Wither
  elseif skill 'Necromancy' >= 70 and skill 'Necromancy' < 90
    cast 'Wither'
    //Lich Form
  elseif skill 'Necromancy' >= 90 and skill 'Necromancy' < 110
    cast 'Lich Form'
    //Vampiric Embrace
  elseif skill 'Necromancy' >= 110 and skill 'Necromancy' < 120
    cast 'Vampiric Embrace'
  endif
else
  stop
endif
//Pause until next cast, change this Value
pause 8000
//End Training
//Meditation
if mana <= 30
  useskill 'Meditation'
  while mana != maxmana
    pause 10000
  endwhile
endif
//End Meditation